# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: jason ryan <jasonwryan@gmail.com>
# Contributor: Christian Rebischke <chris.rebischke@archlinux.org>

pkgbase=profanity
pkgname=('profanity' 'profanity-gtk')
pkgver=0.20.0
pkgrel=2
epoch=1
pkgdesc='Console based XMPP client'
url='https://profanity-im.github.io'
arch=('x86_64')
license=('GPL3')
_clidepends=(
  expat
  glib2
  glibc
  libassuan
  libcurl.so
  libgcrypt
  libgpg-error
  libgpgme.so
  libncursesw.so
  libnotify.so
  libotr
  libreadline.so
  libsignal-protocol-c
  libstrophe.so
  lua
)
_gtkdepends=(
  cairo
  enchant
  gdk-pixbuf2
  libgtk-3.so
  libx11
  libxss
  qrencode
)
makedepends=(
  meson ${_clidepends[@]} ${_gtkdepends[@]}
)
checkdepends=('cmocka')
source=(https://github.com/profanity-im/profanity/archive/${pkgver}/${pkgbase}-${pkgver}.tar.gz)
sha256sums=('a30ed8175176a6d0c4de740e300cd02744e0aebe6eccb010f4a4e5fcffb41414')
sha512sums=('34c35926506eaa9762f0ce05d66aa1b2267b4b5fa37e0ebf27d92b61e5e000bd1bf91414b468fcd2c0a746a4ff3ba1dddc0bb89c41535b262ad5bcbca9321c8a')
b2sums=('c2ac16d4b9d0750c74525f533d27d946fa865571f4c249f05357e3ad7259a3a2efe8b3a01ab9a3013187fe134c17f6dbb16dedfd0bb0e6ec9a021093650665ca')

prepare() {
  cp -a "${srcdir}"/${pkgname}-${pkgver}{,-gtk}
}

build() {
  echo "Building non-gtk variant..."
  (
    local meson_options=(
      -D notifications=enabled
      -D omemo=enabled
      -D otr=enabled
      -D pgp=enabled
      -D plugins=enabled
    )

    arch-meson ${pkgname}-${pkgver} build "${meson_options[@]}"
    meson compile -C build
  )
  echo "Building gtk variant..."
  (
    local meson_options=(
      -D gdk-pixbuf=enabled
      -D notifications=enabled
      -D omemo=enabled
      -D omemo-qrcode=enabled
      -D otr=enabled
      -D pgp=enabled
      -D plugins=enabled
      -D spellcheck=enabled
      -D tray=enabled
    )

    arch-meson ${pkgname}-${pkgver} build-gtk "${meson_options[@]}"
    meson compile -C build-gtk
  )
}

package_profanity() {
  depends=(
    ${_clidepends[@]}
  )
  meson install -C build --destdir "${pkgdir}"
}

package_profanity-gtk() {
  pkgdesc+=' (gtk support)'
  depends=(
    ${_clidepends[@]} ${_gtkdepends[@]}
  )
  provides=('profanity')
  conflicts=('profanity')
  meson install -C build-gtk --destdir "${pkgdir}"
}

# vim: ts=2 sw=2 et:
